InfoAjuda

Projeto 4 - Concluído (Algoritmo)

Projeto 4 - Concluído (Algoritmo)
« Online: Outubro 31, 2017, 07:16:36 am »
Citar
algoritmo "atividade semanal 4"
var
   turno, cat_renda, renda, turn: vetor[1..5] de caractere
   mensalidade, valor_mensal: vetor[1..5] de real
   alunos, cont, total_renda_b, total_renda_n:inteiro
   nome: vetor[1..5] de caractere
   
   
procedimento cabecalho()
inicio
   escreval("------------------------------------")
   escreval(" ESCOLA DO SABER - INSCRIÇÕES 2017")
   escreval("------------------------------------")
   escreval()
   escreval()
fimprocedimento


inicio
   total_renda_b <- 0
   total_renda_n <- 0
   alunos <- 0
   cont <- 1
   
   
   repita
   cabecalho()
   escreval("ALUNO ", cont)
   
// INFOMAÇÕES SOBRE A MENSALIDADE DO CURSO
   escreval("Digite o valor da mensalidade:")
   escreva("R$ ")
   leia(valor_mensal[cont])
         enquanto ((valor_mensal[cont]<=0)) faca
                  escreval("Valor incorreto. Digite uma valor maior que 0.")
                  leia(valor_mensal[cont])
         fimenquanto
         limpatela()

// NOME DO ALUNO
   cabecalho()
   escreval("Digite o nome do aluno: ")
   leia(nome[cont])
   limpatela()

// INFORMAÇÕES SOBRE O TURNO DE ESTUDOS
   cabecalho()
   escreval("EM QUAL TURNO ", maiusc(nome[cont])," DESEJA ESTUDAR?")
   escreval("-------------------------------------")
   escreval("Digite: [M] - Turno da manhã")
   escreval("        [T] - Turno da tarde")
   escreval("        [N] - Turno da noite")
   leia(turno[cont])
         enquanto ((turno[cont] <> "M") e (turno[cont] <> "T") e (turno[cont] <> "N")) faca
                  escreval("Turno inválido. Digite novamente: ")
                  leia(turno[cont])
         fimenquanto
         limpatela()

   se turno[cont] = "M" entao
      turn[cont] <- "MANHÃ"
   fimse

   se turno[cont] = "T" entao
      turn[cont] <- "TARDE"
   fimse

   se turno[cont] = "N" entao
      turn[cont] <- "NOITE"
   fimse

// INFOMAÇÕES SOBRE A RENDA FAMILIAR DO ALUNO
   cabecalho()
   escreval("CATEGORIA DE RENDA FAMILIAR DE ", maiusc(nome[cont]))
   escreval("-------------------------------------")
   escreval("Digite: - Baixa Renda")
   escreval("        [N] - Renda Normal")
   leia(cat_renda[cont])
          enquanto ((cat_renda[cont] <> "B") e (cat_renda[cont] <> "N")) faca
                   escreval("Categoria de renda inválida. Digite novamente: ")
                   leia(cat_renda[cont])
          fimenquanto
          limpatela()

   se cat_renda[cont] = "B" entao
     renda[cont] <- "SIM"
     total_renda_b <- total_renda_b + 1
   senao
     renda[cont] <- "NÃO"
     total_renda_n <- total_renda_n + 1
   fimse

// CÁLCULOS
   se (turno[cont] = "M") e (cat_renda[cont] = "N") entao
      mensalidade[cont] <- valor_mensal[cont]
   fimse

   se (turno[cont] = "M") e (cat_renda[cont] = "B") entao
      mensalidade[cont] <- valor_mensal[cont] - (valor_mensal[cont] * 0.1)
   fimse

   se (turno[cont] = "T") e (cat_renda[cont] = "N") entao
      mensalidade[cont] <- valor_mensal[cont] - (valor_mensal[cont] * 0.05)
   fimse

   se (turno[cont] = "T") e (cat_renda[cont] = "B") entao
      mensalidade[cont] <- valor_mensal[cont] - (valor_mensal[cont] * 0.15)
   fimse

   se (turno[cont] = "N") e (cat_renda[cont] = "N") entao
      mensalidade[cont] <- valor_mensal[cont] - (valor_mensal[cont] * 0.1)
   fimse

   se (turno[cont] = "N") e (cat_renda[cont] = "B") entao
      mensalidade[cont] <- valor_mensal[cont] - (valor_mensal[cont] * 0.2)
   fimse

   alunos <- alunos + 1
   cont <- cont + 1

   ate (alunos = 5)
   limpatela

   para cont de 1 ate 5 faca

   escreval("------------------------------------")
   escreval(" INSCRIÇÃO REALIZADA COM SUCESSO")
   escreval("------------------------------------")

   escreval("ALUNO ",cont)
   escreval("NOME DO ALUNO: ", maiusc(nome[cont]))
   escreval("ALUNO BAIXA RENDA: ", renda[cont])
   escreval("TURNO ESCOLHIDO: ", turn[cont])
   escreval("VALOR DA MENSALIDADE DO ALUNO: R$", mensalidade[cont]:1:2)
   escreval("VALOR TOTAL DO CURSO (12 MESES): R$", mensalidade[cont] * 12:1:2)
   escreval()
   escreval()
   fimpara

   //RELÁTORIO FINAL COM O TOTAL DE ALUNO COM RENDA "B" E "N"
   escreval("|--------------------------------------------|")
   escreval("|       RELATÓRIO DE RENDA DOS ALUNOS        |")
   escreval("|--------------------------------------------|")
   escreval("|TOTAL DE ALUNOS INSCRITOS: ",total_renda_b + total_renda_n,"               |")
   escreval("|TOTAL DE ALUNOS BAIXA RENDA: ",total_renda_b,"             |")
   escreval("|TOTAL DE ALUNOS COM RENDA NORMAL: ",total_renda_n,"        |")
   escreval("|--------------------------------------------|")

fimalgoritmo
« Última modificação: Novembro 15, 2017, 03:13:21 pm por DiegoB. »